Serienbrief - Jeder Datenatz als PDF speichern

Sie möchten einen Serienbrief erstellen und dabei jeden einzelnen Datensatz als eigene PDF-Datei speichern.

Mit folgendem VBA-Code funktioniert dies!

Vorgehen

1. Word-Datei (Brief) erstellen und im Dateiformat .docm speichern
2. Word-Datei (Brief) normal mit der Datenquelle verbinden
3. Seriendruckfelder einfügen
4. Code (siehe unten) in neues Modul im Word-VBA-Editor kopieren
5. Makro im VBA-Editor laufen lassen (F5)

Wichtig / Zu beachten
Damit der Code funktioniert, müssen Sie
- den Pfad definieren (siehe "Pfad definieren")
- optional: den Unterordner definieren (siehe "Unterordner definieren")
- die Regel für den Dateinamen definieren (siehe "Dateinahmen definieren für PDF-Dateien").

VBA-Code

Sub Serienbrief()

'Definition der Variablen
Dim iBrief As Integer, sBrief As String
Dim AppShell As Object
Dim BrowseDir As Variant
Dim Path As String

'Errhorhandler
On Error GoTo ErrorHandling


'Pfad und Unterordner definieren, in welchen die PDF-Dateien gespeichert werden sollen
'=========================================================================
'Pfad definieren
Path = "D:\Ordner"

'Unterordner definieren
Path = Path & "\Serienbrief_" & Format(Now, "yyyymmdd_hhmm") & "\"

'Erstellt den Unterordner
MkDir Path

On Error GoTo ErrorHandling





'Applikation ausblenden - für bessere Performance
MsgBox "Serienbriefe werden exportiert. Dieser Vorgang kann einige Minuten dauern - Microsoft Word wird während dieser Zeit ausgeblendet", vbOKOnly + vbInformation
Application.Visible = False

'Erstelle Serienbrief und Export als PDF
'================================
With ActiveDocument.MailMerge
.DataSource.ActiveRecord = 1
Do
.Destination = wdSendToNewDocument
.SuppressBlankLines = True

With .DataSource
.FirstRecord = .ActiveRecord
.LastRecord = .ActiveRecord

'Dateinamen definieren für PDF-Dateien
'====================================
sBrief = Path & .DataFields("BPNr").Value & "_" & .DataFields("Name").Value & ".pdf"

End With

.Execute Pause:=False



If .DataSource.DataFields("BPNr").Value > "" Then
ActiveDocument.SaveAs FileName:=sBrief, FileFormat:=wdFormatPDF
End If
ActiveDocument.Close False



If .DataSource.ActiveRecord < .DataSource.RecordCount Then
.DataSource.ActiveRecord = wdNextRecord
Else
Exit Do
End If

'Nächster Datensatz
Loop

End With




'Errorhandling
ErrorHandling:
Application.Visible = True

If Err.Number = 76 Then
MsgBox "Der ausgewählte Speicherort ist ungültig", vbOKOnly + vbCritical
ElseIf Err.Number = 5852 Then
MsgBox "Das Dokument ist kein Serienbrief"
ElseIf Err.Number = 4198 Then
MsgBox "Der ausgewählte Speicherort ist ungültig", vbOKOnly + vbCritical
ElseIf Err.Number = 91 Then
MsgBox "Exportieren von Serienbriefen abgebrochen", vbOKOnly + vbExclamation
ElseIf Err.Number > 0 Then
MsgBox "Unbekannter Fehler: " & Err.Number & " - Bitte Makro erneut ausführen.", vbOKOnly + vbCritical
Else
MsgBox "Serienbriefe erfolgreich exportiert", vbOKOnly + vbInformation
End If


End Sub